# slog.irc   -   gives a mirc style logging system
#                    by Zed 

# write to a log file. /slog.write file message
alias slog.write {
	@ fd = open(~/logs/$0 W)
	@ write($fd $1-)
	@ close($fd)
}

#Init
eval echo $cparse("%GI%gnitiating %GS%gLOG")

# Incoming priv msgs > log.nick
on #-msg 371371 * slog.write log.$0    [$Z] $0: $1-

# Outgoing priv msgs > log.nick
on #-send_msg 371371 * slog.write log.$0 => [$Z] $N: $1-

# Incoming DCC msgs > log.nick
on #-dcc_chat 371371 * slog.write log.=$0    [$Z] $0: $1-

# Outgoing DCC msgs > log.nick
on #-send_dcc_chat 371371 * slog.write log.=$0 => [$Z] $N: $1-

# Incoming channel msgs > log.#channel
on #-public 371371 * slog.write log.$1    [$Z] <$0> $2-

# Outgoing channel msgs > log.#channel
on #-send_public 371371 * slog.write log.$0 => [$Z] <$N> $1-

# Outgoing actions > log.[nick/#channel]
on #-send_action 371371 * slog.write log.$0 => [$Z] $N $1-

# Incoming actions > log.[nick/#channel]
on #-action 371371 * {
	if ([$[1]1] == [#])
	{ slog.write log.$1    [$Z] $0 $2- }
	{ slog.write log.$0 <= [$Z] $0 $2- }
}

# parts from channel > log.#channel
on #-leave 371371 * slog.write log.$1    [$Z] <=> $0  $2- has left $1

# joins on channel > log.#channel 
on #-join 371371 * slog.write log.$1    [$Z] <=> $0  $2- has joined $1

# Topic changes > log.#channel
on #-topic 371371 * slog.write log.$1    [$Z] <=> $0 has changed the topic on channel $1 to $2-

# Nickname changes > log.#channel
on #-channel_nick 371371 * slog.write log.$0    [$Z] <=> $1 is now known as $2

# Quits > log.#channel
on #-channel_signoff 371371 * slog.write log.$0    [$Z] <=> SignOff: $1  $0 $2-

# Channel mode changes > log.#channel
on #-mode 371371 * slog.write log.$1    [$Z] <=> mode $1  $2-  by $1

# Log ctcps > ctcps
on #-ctcp 371371 * slog.write ctcps [$Z] $0 \($userhost()\): $2-